git.tinc-vpn.org Git - tinc/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.61)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR([src/tincd.c])
   6 AM_INIT_AUTOMAKE(tinc, 1.0.16)
   7 AC_CONFIG_HEADERS([config.h])
   8 AM_MAINTAINER_MODE
   9
  10 # Enable GNU extensions.
  11 # Define this here, not in acconfig's @TOP@ section, since definitions
  12 # in the latter don't make it into the configure-time tests.
  13 AC_GNU_SOURCE
  14 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  15
  16 dnl Checks for programs.
  17 AC_PROG_CC_C99
  18 AC_PROG_CPP
  19 AC_PROG_INSTALL
  20 AC_PROG_LN_S
  21 AC_PROG_RANLIB
  22
  23 dnl Check and set OS
  24
  25 AC_CANONICAL_HOST
  26
  27 case $host_os in
  28   *linux*)
  29     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  30     [ rm -f src/device.c; ln -sf linux/device.c src/device.c ]
  31   ;;
  32   *freebsd*)
  33     AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD])
  34     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  35   ;;
  36   *darwin*)
  37     AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)])
  38     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  39   ;;
  40   *solaris*)
  41     AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS])
  42     [ rm -f src/device.c; ln -sf solaris/device.c src/device.c ]
  43   ;;
  44   *openbsd*)
  45     AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD])
  46     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  47   ;;
  48   *netbsd*)
  49     AC_DEFINE(HAVE_NETBSD, 1, [NetBSD])
  50     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  51   ;;
  52   *dragonfly*)
  53     AC_DEFINE(HAVE_DRAGONFLY, 1, [DragonFly])
  54     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  55   ;;
  56   *bsd*)
  57     AC_MSG_WARN("Unknown BSD variant, tinc might not compile or work!")
  58     AC_DEFINE(HAVE_BSD, 1, [Unknown BSD variant])
  59     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  60   ;;
  61   *cygwin*)
  62     AC_DEFINE(HAVE_CYGWIN, 1, [Cygwin])
  63     [ rm -f src/device.c; ln -sf cygwin/device.c src/device.c ]
  64   ;;
  65   *mingw*)
  66     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  67     [ rm -f src/device.c; cp -f src/mingw/device.c src/device.c ]
  68     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32"
  69   ;;
  70   *)
  71     AC_MSG_ERROR("Unknown operating system.")
  72   ;;
  73 esac
  74
  75 AC_ARG_ENABLE(tunemu,
  76   AS_HELP_STRING([--enable-tunemu], [enable support for the tunemu driver]),
  77   [ AC_DEFINE(ENABLE_TUNEMU, 1, [Support for tunemu])
  78     tunemu=true
  79   ]
  80 )
  81
  82 AC_ARG_WITH(windows2000,
  83   AS_HELP_STRING([--with-windows2000], [compile with support for Windows 2000. This disables support for tunneling over existing IPv6 networks.]),
  84   [AC_DEFINE(WITH_WINDOWS2000, 1, [Compile with support for Windows 2000])]
  85 )
  86
  87 AM_CONDITIONAL(TUNEMU, test "$tunemu" = true)
  88
  89 AC_CACHE_SAVE
  90
  91 if test -d /sw/include ; then
  92   CPPFLAGS="$CPPFLAGS -I/sw/include"
  93 fi
  94 if test -d /sw/lib ; then
  95   LIBS="$LIBS -L/sw/lib"
  96 fi
  97
  98 dnl Checks for libraries.
  99
 100 dnl Checks for header files.
 101 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 102
 103 AC_HEADER_STDC
 104 AC_CHECK_HEADERS([stdbool.h syslog.h sys/file.h sys/ioctl.h sys/mman.h sys/param.h sys/resource.h sys/socket.h sys/time.h time.h sys/uio.h sys/wait.h netdb.h arpa/inet.h dirent.h])
 105 AC_CHECK_HEADERS([net/if.h net/if_types.h linux/if_tun.h net/if_tun.h net/tun/if_tun.h net/if_tap.h net/tap/if_tap.h net/ethernet.h net/if_arp.h netinet/in_systm.h netinet/in.h netinet/in6.h],
 106   [], [], [#include "have.h"]
 107 )
 108 AC_CHECK_HEADERS([netinet/if_ether.h netinet/ip.h netinet/ip6.h],
 109   [], [], [#include "have.h"]
 110 )
 111 AC_CHECK_HEADERS([netinet/tcp.h netinet/ip_icmp.h netinet/icmp6.h],
 112   [], [], [#include "have.h"]
 113 )
 114
 115 dnl Checks for typedefs, structures, and compiler characteristics.
 116 AC_C_CONST
 117 AC_C_VOLATILE
 118 AC_TYPE_PID_T
 119 AC_TYPE_SIZE_T
 120 AC_HEADER_TIME
 121 AC_STRUCT_TM
 122
 123 tinc_ATTRIBUTE(__malloc__)
 124
 125 AC_CHECK_TYPES([socklen_t, struct ether_header, struct arphdr, struct ether_arp, struct in_addr, struct addrinfo, struct ip, struct icmp, struct in6_addr, struct sockaddr_in6, struct ip6_hdr, struct icmp6_hdr, struct nd_neighbor_solicit, struct nd_opt_hdr], , ,
 126   [#include "have.h"]
 127 )
 128
 129 dnl Checks for library functions.
 130 AC_FUNC_MEMCMP
 131 AC_FUNC_ALLOCA
 132 AC_TYPE_SIGNAL
 133 AC_CHECK_FUNCS([asprintf daemon fchmod flock ftime fork get_current_dir_name gettimeofday mlockall pselect putenv random select strdup strerror strsignal strtol system unsetenv usleep vsyslog writev],
 134   [], [], [#include "have.h"]
 135 )
 136 AC_FUNC_MALLOC
 137 AC_FUNC_REALLOC
 138
 139 dnl Support for SunOS
 140
 141 AC_CHECK_FUNC(socket, [], [
 142   AC_CHECK_LIB(socket, connect)
 143 ])
 144 AC_CHECK_FUNC(gethostbyname, [], [
 145   AC_CHECK_LIB(nsl, gethostbyname)
 146 ])
 147
 148 AC_CHECK_DECLS([freeaddrinfo, gai_strerror, getaddrinfo, getnameinfo],
 149   [], [], [#include "have.h"]
 150 )
 151
 152 AC_CACHE_SAVE
 153
 154 dnl These are defined in files in m4/
 155
 156 tinc_ZLIB
 157 tinc_LZO
 158 tinc_OPENSSL
 159
 160 dnl Check if support for jumbograms is requested
 161 AC_ARG_ENABLE(jumbograms,
 162   AS_HELP_STRING([--enable-jumbograms], [enable support for jumbograms (packets up to 9000 bytes)]),
 163   [ AC_DEFINE(ENABLE_JUMBOGRAMS, 1, [Support for jumbograms (packets up to 9000 bytes)]) ]
 164 )
 165
 166 AC_SUBST(INCLUDES)
 167
 168 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile lib/Makefile m4/Makefile])
 169
 170 AC_OUTPUT