git.tinc-vpn.org Git - tinc/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl $Id: configure.in,v 1.13.2.35 2001/10/13 13:53:07 guus Exp $
   4
   5 AC_INIT(src/tincd.c)
   6 AM_INIT_AUTOMAKE(tinc, 1.0-cvs)
   7 AM_CONFIG_HEADER(config.h)
   8
   9 dnl Include the macros from the m4/ directory
  10 AM_ACLOCAL_INCLUDE(m4)
  11
  12 # Enable GNU extensions.
  13 # Define this here, not in acconfig's @TOP@ section, since definitions
  14 # in the latter don't make it into the configure-time tests.
  15 AC_DEFINE([_GNU_SOURCE], [__USE_BSD])
  16
  17 ALL_LINGUAS="nl"
  18
  19 dnl Checks for programs.
  20 AC_PROG_CC
  21 AC_PROG_CPP
  22 AC_PROG_GCC_TRADITIONAL
  23 AC_PROG_AWK
  24 AC_PROG_INSTALL
  25 AC_PROG_LN_S
  26 AC_PROG_MAKE_SET
  27 jm_PERL
  28
  29
  30 AC_ISC_POSIX
  31
  32 dnl Check and set OS
  33
  34 AC_CANONICAL_HOST
  35
  36 case $host_os in
  37   *linux*)
  38     AC_DEFINE(HAVE_LINUX)
  39     [ ln -sf linux/device.c src/device.c ]
  40   ;;
  41   *freebsd*)
  42     AC_DEFINE(HAVE_FREEBSD)
  43     [ ln -sf freebsd/device.c src/device.c ]
  44   ;;
  45   *solaris*)
  46     AC_DEFINE(HAVE_SOLARIS)
  47     [ ln -sf solaris/device.c src/device.c ]
  48   ;;
  49   *openbsd*)
  50     AC_DEFINE(HAVE_OPENBSD)
  51     [ ln -sf openbsd/device.c src/device.c ]
  52   ;;
  53 esac
  54
  55 AC_CACHE_SAVE
  56
  57 dnl Checks for libraries.
  58
  59 dnl Checks for header files.
  60 AC_HEADER_STDC
  61 AC_CHECK_HEADERS([fcntl.h limits.h sys/ioctl.h syslog.h unistd.h \
  62 sys/time.h malloc.h strings.h sys/file.h])
  63
  64 dnl Checks for typedefs, structures, and compiler characteristics.
  65 AC_C_CONST
  66 AC_TYPE_PID_T
  67 AC_TYPE_SIZE_T
  68 AC_HEADER_TIME
  69 AC_STRUCT_TM
  70
  71 dnl Checks for library functions.
  72 AC_FUNC_MEMCMP
  73 AC_FUNC_ALLOCA
  74 AC_TYPE_SIGNAL
  75 AC_CHECK_FUNCS([ftime socket select strtol strerror flock unsetenv \
  76 asprintf putenv strdup fcloseall daemon strsignal get_current_dir_name])
  77 jm_FUNC_MALLOC
  78 jm_FUNC_REALLOC
  79
  80 AM_GNU_GETTEXT
  81
  82
  83 dnl Support for SunOS
  84
  85 AC_CHECK_FUNC(socket, [], [
  86   AC_CHECK_LIB(socket, connect)
  87 ])
  88 AC_CHECK_FUNC(gethostbyname, [], [
  89   AC_CHECK_LIB(nsl, gethostbyname)
  90 ])
  91
  92 AC_CACHE_SAVE
  93
  94 dnl These are defined in files in m4/
  95 tinc_TUNTAP
  96 tinc_OPENSSL
  97
  98 dnl Check if checkpoint tracing has to be enabled
  99 AC_ARG_ENABLE(tracing,
 100   [  --enable-tracing        enable checkpoint tracing (debugging only)],
 101   [ AC_DEFINE(ENABLE_TRACING) ]
 102 )
 103
 104 AC_SUBST(INCLUDES)
 105
 106 AC_OUTPUT(Makefile
 107 src/Makefile
 108 doc/Makefile
 109 doc/es/Makefile
 110 intl/Makefile
 111 lib/Makefile
 112 m4/Makefile
 113 po/Makefile.in
 114 redhat/Makefile
 115 debian/Makefile)