git.tinc-vpn.org Git - tinc/blob - m4/realloc.m4

   1 #serial 1
   2
   3 dnl From Jim Meyering.
   4 dnl Determine whether realloc works when both arguments are 0.
   5 dnl If it doesn't, arrange to use the replacement function.
   6 dnl
   7 dnl If you use this macro in a package, you should
   8 dnl add the following two lines to acconfig.h:
   9 dnl  /* Define to rpl_realloc if the replacement function should be used.  */
  10 dnl  #undef realloc
  11 dnl
  12
  13 AC_DEFUN(jm_FUNC_REALLOC,
  14 [
  15  if test x = y; then
  16    dnl This code is deliberately never run via ./configure.
  17    dnl FIXME: this is a gross hack to make autoheader put an entry
  18    dnl for this symbol in config.h.in.
  19    AC_CHECK_FUNCS(DONE_WORKING_REALLOC_CHECK)
  20  fi
  21  dnl xmalloc.c requires that this symbol be defined so it doesn't
  22  dnl mistakenly use a broken realloc -- as it might if this test were omitted.
  23  AC_DEFINE(HAVE_DONE_WORKING_REALLOC_CHECK, 1, [Needed for xmalloc.c])
  24
  25  AC_CACHE_CHECK([for working realloc], jm_cv_func_working_realloc,
  26   [AC_TRY_RUN([
  27     char *realloc ();
  28     int
  29     main ()
  30     {
  31       exit (realloc (0, 0) ? 0 : 1);
  32     }
  33           ],
  34          jm_cv_func_working_realloc=yes,
  35          jm_cv_func_working_realloc=no,
  36          dnl When crosscompiling, assume realloc is broken.
  37          jm_cv_func_working_realloc=no)
  38   ])
  39   if test $jm_cv_func_working_realloc = no; then
  40     dnl This was: LIBOBJS="$LIBOBJS realloc.$ac_objext"
  41     AC_LIBOBJ([realloc])
  42     AC_DEFINE(realloc, rpl_realloc, [Replacement realloc()])
  43   fi
  44 ])