git.tinc-vpn.org Git - tinc/blob - test/integration/meson.build

   1 tests = [
   2   'basic.py',
   3   'cmd_dump.py',
   4   'cmd_fsck.py',
   5   'cmd_join.py',
   6   'cmd_keys.py',
   7   'cmd_misc.py',
   8   'cmd_net.py',
   9   'cmd_sign_verify.py',
  10   'commandline.py',
  11   'executables.py',
  12   'import_export.py',
  13   'invite.py',
  14   'invite_tinc_up.py',
  15   'proxy.py',
  16   'sandbox.py',
  17   'scripts.py',
  18   'security.py',
  19   'splice.py',
  20   'sptps_basic.py',
  21   'variables.py',
  22 ]
  23
  24 if opt_crypto != 'nolegacy'
  25   tests += [
  26     'algorithms.py',
  27     'legacy_protocol.py',
  28   ]
  29 endif
  30
  31 if os_name == 'linux'
  32   tests += [
  33     'ns_ping.py',
  34     'compression.py',
  35   ]
  36 endif
  37
  38 exe_splice = executable(
  39   'splice',
  40   sources: 'splice.c',
  41   dependencies: deps_common,
  42   implicit_include_directories: false,
  43   include_directories: inc_conf,
  44   build_by_default: false,
  45 )
  46
  47 env_vars = {
  48   'TINC_PATH': exe_tinc.full_path(),
  49   'TINCD_PATH': exe_tincd.full_path(),
  50   'PYTHON_PATH': python_path,
  51   'SPLICE_PATH': exe_splice.full_path(),
  52   'SPTPS_TEST_PATH': exe_sptps_test.full_path(),
  53   'SPTPS_KEYPAIR_PATH': exe_sptps_keypair.full_path(),
  54 }
  55
  56 deps_test = [
  57   exe_tinc,
  58   exe_tincd,
  59   exe_splice,
  60   exe_sptps_test,
  61   exe_sptps_keypair,
  62 ]
  63
  64 test_wd = meson.current_build_dir()
  65 test_src = meson.current_source_dir()
  66
  67 foreach test_name : tests
  68   if meson_version.version_compare('>=0.52')
  69     env = environment(env_vars)
  70   else
  71     env = environment()
  72     foreach k, v : env_vars
  73       env.set(k, v)
  74     endforeach
  75   endif
  76   env.set('TEST_NAME', test_name)
  77
  78   test(test_name,
  79        python,
  80        args: test_src / test_name,
  81        suite: 'integration',
  82        timeout: 60,
  83        env: env,
  84        depends: deps_test,
  85        workdir: test_wd)
  86 endforeach
  87