From: Guus Sliepen <guus@tinc-vpn.org>
Date: Sun, 15 May 2011 10:06:21 +0000 (+0200)
Subject: Add an autoconf check for the curses library.
X-Git-Tag: release-1.1pre1~58
X-Git-Url: https://git.tinc-vpn.org/git/browse?a=commitdiff_plain;h=ec495b2f15fc5ae22136c226c7966caf51f643f8;p=tinc

Add an autoconf check for the curses library.
---

diff --git a/configure.in b/configure.in
index 7c050139..ccc0d26c 100644
--- a/configure.in
+++ b/configure.in
@@ -154,6 +154,7 @@ dnl These are defined in files in m4/
 
 AC_ARG_WITH(libgcrypt, AC_HELP_STRING([--with-libgcrypt], [enable use of libgcrypt instead of OpenSSL])], [])
 
+tinc_CURSES
 tinc_LIBEVENT
 tinc_ZLIB
 tinc_LZO
diff --git a/m4/curses.m4 b/m4/curses.m4
new file mode 100644
index 00000000..1001f497
--- /dev/null
+++ b/m4/curses.m4
@@ -0,0 +1,38 @@
+dnl Check to find the curses headers/libraries
+
+AC_DEFUN([tinc_CURSES],
+[
+  AC_ARG_ENABLE([curses],
+    AS_HELP_STRING([--disable-curses], [disable curses support]))
+  AS_IF([test "x$enable_curses" != "xno"], [
+  AC_DEFINE(HAVE_CURSES, 1, [have curses support])
+    AC_ARG_WITH(curses,
+      AS_HELP_STRING([--with-curses=DIR], [curses base directory, or:]),
+      [curses="$withval"
+       CPPFLAGS="$CPPFLAGS -I$withval/include"
+       LDFLAGS="$LDFLAGS -L$withval/lib"]
+    )
+
+    AC_ARG_WITH(curses-include,
+      AS_HELP_STRING([--with-curses-include=DIR], [curses headers directory]),
+      [curses_include="$withval"
+       CPPFLAGS="$CPPFLAGS -I$withval"]
+    )
+
+    AC_ARG_WITH(curses-lib,
+      AS_HELP_STRING([--with-curses-lib=DIR], [curses library directory]),
+      [curses_lib="$withval"
+       LDFLAGS="$LDFLAGS -L$withval"]
+    )
+
+    AC_CHECK_HEADERS(curses.h,
+      [],
+      [AC_MSG_ERROR("curses header files not found."); break]
+    )
+
+    AC_CHECK_LIB(curses, initscr,
+      [LIBS="$LIBS -lcurses"],
+      [AC_MSG_ERROR("curses libraries not found.")]
+    )
+  ])
+])